Add CartesianIterator

src/Iteration/CartesianIterator.jl

@@ -0,0 +1,45 @@
+# iterator over the set of vectors `v` of length n containing positive integers
+# such that `v[i] ≤ ref[i]` for all `i`
+#
+# NOTE: The iterator can be instructed to not create copies of the vectors,
+# which are however modified during iteration.
+struct CartesianIterator{V<:AbstractVector{Int}}
+    ref::V
+    copy::Bool
+
+    function CartesianIterator(ref::V, copy::Bool=true) where {V}
+        @assert length(ref) > 0 "need at least one entry"
+        @assert all(>(0), ref) "all entries must be positive"
+        return new{V}(ref, copy)
+    end
+end
+
+function Base.length(it::CartesianIterator)
+    return prod(it.ref)
+end
+
+Base.eltype(::Type{<:CartesianIterator{V}}) where {V} = V
+
+function Base.iterate(it::CartesianIterator)
+    state = ones(Int, length(it.ref))
+    return (state, state)
+end
+
+function Base.iterate(it::CartesianIterator, state)
+    if it.copy
+        state = copy(state)
+    end
+    i = length(it.ref) + 1
+    @inbounds while true
+        i -= 1
+        if i == 0
+            return nothing
+        end
+        if state[i] < it.ref[i]
+            state[i] += 1
+            break
+        end
+        state[i] = 1
+    end
+    return (state, state)
+end

src/Iteration/Iteration.jl

@@ -8,13 +8,15 @@ module Iteration
 using SparseArrays
 
 export EmptyIterator, SingletonIterator, VectorIterator,
-       StrictlyIncreasingIndices, NondecreasingIndices, BitvectorIterator
+       StrictlyIncreasingIndices, NondecreasingIndices, BitvectorIterator,
+       CartesianIterator
 
 include("EmptyIterator.jl")
 include("SingletonIterator.jl")
 include("VectorIterator.jl")
 include("StrictlyIncreasingIndices.jl")
 include("NondecreasingIndices.jl")
 include("BitvectorIterator.jl")
+include("CartesianIterator.jl")
 
 end  # module

test/Iteration/CartesianIterator.jl

@@ -0,0 +1,13 @@
+using ReachabilityBase.Iteration
+
+@test_throws AssertionError CartesianIterator(Int[])
+@test_throws AssertionError CartesianIterator([-1])
+
+ci = CartesianIterator([2, 3], false)
+ci2 = CartesianIterator([2, 3], true)
+@test length(ci) == length(ci2) == 6
+@test [copy(v) for v in ci] == collect(ci2) == [[1, 1], [1, 2], [1, 3], [2, 1], [2, 2], [2, 3]]
+
+ci = CartesianIterator([1, 1, 1], true)
+@test length(ci) == 1
+@test collect(ci) == [[1, 1, 1]]

test/runtests.jl

@@ -31,6 +31,9 @@ end
     @testset "StrictlyIncreasingIndices" begin
         include("Iteration/StrictlyIncreasingIndices.jl")
     end
+    @testset "CartesianIterator" begin
+        include("Iteration/CartesianIterator.jl")
+    end
 end
 @testset "Timing" begin
     include("Timing/timing.jl")