First commit for meta-zturn repository. Very crude, but it does boot …

…for me. YMMV.

README.md

@@ -0,0 +1,15 @@
+meta-zturn
+==========
+
+This layer is a crude first stab at creating OpenEmbedded/Angstrom support for the Myir Z-Turn 7020 board. The purpose was for me to get to know the chip, but hey, maybe someone could also find it useful.
+
+For more information see:
+https://wiki.hackerspace.pl/projects:zturn-hackers
+https://github.com/q3k/zturn-stuff
+(Thanks guys!)
+
+Based on the above the information, ZTurn support was added to newer versions of u-boot-xlnx and linux-xlnx, much newer than what Myir was running.
+
+Known issues:
+
+Connman takes ages to initialise, apparantly because it is blocking on "random: nonblocking pool is initialized". Added haveged to the image, and tweaked connman.service to at least not block log-in.

conf/layer.conf

@@ -0,0 +1,9 @@
+# We might have a conf and classes directory, append to BBPATH
+BBPATH .= ":${LAYERDIR}"
+
+# We have a recipes directory, add to BBFILES
+BBFILES += "${LAYERDIR}/recipes*/*/*.bb ${LAYERDIR}/recipes*/*/*.bbappend"
+
+BBFILE_COLLECTIONS += "meta-zturn"
+BBFILE_PATTERN_meta-zturn := "^${LAYERDIR}/"
+BBFILE_PRIORITY_meta-zturn = "10"

conf/machine/include/machine-xilinx-board.inc

@@ -0,0 +1,6 @@
+# Default Xilinx Board settings
+
+EXTRA_IMAGEDEPENDS += "virtual/bootloader"
+
+IMAGE_BOOT_FILES ?= "${KERNEL_IMAGETYPE} ${UBOOT_BINARY}"
+

conf/machine/include/machine-xilinx-default.inc

@@ -0,0 +1,56 @@
+# Default Xilinx BSP Machine settings
+
+MACHINE_FEATURES_BACKFILL_CONSIDERED += "rtc"
+
+# MicroBlaze cannot handle the execution of qemu-linux-user for gobject-introspection-data
+MACHINE_FEATURES_BACKFILL_CONSIDERED_append_microblaze = " qemu-usermode"
+
+# File System Configuration
+IMAGE_FSTYPES ?= "tar.gz cpio cpio.gz.u-boot"
+IMAGE_CLASSES += "image_types_uboot"
+
+# Kernel Configuration
+XILINX_DEFAULT_KERNEL := "linux-xlnx"
+XILINX_DEFAULT_KERNEL_microblaze := "linux-yocto"
+XILINX_DEFAULT_KERNEL_zynqmp := "linux-yocto"
+
+PREFERRED_PROVIDER_virtual/kernel ??= "${XILINX_DEFAULT_KERNEL}"
+PREFERRED_VERSION_linux-xlnx ?= "4.6%"
+PREFERRED_VERSION_linux-yocto ?= "4.8%"
+
+# U-Boot Configuration
+XILINX_DEFAULT_UBOOT := "u-boot-xlnx"
+XILINX_DEFAULT_UBOOT_zynqmp := "u-boot"
+PREFERRED_PROVIDER_virtual/bootloader ??= "${XILINX_DEFAULT_UBOOT}"
+
+UBOOT_SUFFIX ?= "img"
+UBOOT_SUFFIX_zynqmp ?= "bin"
+UBOOT_SUFFIX_microblaze ?= "bin"
+
+# u-boot-xlnx setups up all zynq configs to have embedded device trees (OF_EMBED=y)
+UBOOT_OFEMBED ?= ""
+UBOOT_OFEMBED_zynq ?= "${@bb.utils.contains_any('PREFERRED_PROVIDER_virtual/bootloader', 'u-boot-xlnx u-boot-xlnx-dev', '', '-dtb', d)}"
+
+UBOOT_BINARY ?= "u-boot${UBOOT_OFEMBED}.${UBOOT_SUFFIX}"
+UBOOT_ELF ?= "u-boot"
+UBOOT_ELF_aarch64 ?= "u-boot.elf"
+
+# kernel modules for ZynqMP
+MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS_append_zynqmp = " \
+		${@bb.utils.contains('MACHINE_FEATURES', 'mali', bb.utils.contains('PREFERRED_PROVIDER_virtual/kernel', 'linux-xlnx', 'kernel-module-mali', '', d), '', d)} \
+		"
+XSERVER ?= " \
+	xserver-xorg \
+	xf86-input-evdev \
+	xf86-input-mouse \
+	xf86-input-keyboard \
+	xf86-video-fbdev \
+	${XSERVER_EXT} \
+	"
+
+XSERVER_EXT ?= ""
+XSERVER_EXT_zynqmp ?= " \
+	${@bb.utils.contains('MACHINE_FEATURES', 'mali', bb.utils.contains('DISTRO_FEATURES', 'opengl', 'xserver-xorg-extension-glx', '', d), '', d)} \
+	xf86-video-armsoc \
+	"
+

conf/machine/include/machine-xilinx-qemu.inc

@@ -0,0 +1,35 @@
+EXTRA_IMAGEDEPENDS += "qemu-native qemu-helper-native"
+
+def qemu_default_dtb(d):
+    if d.getVar("MACHINE_DEVICETREE", True):
+        dtbs = d.getVar("MACHINE_DEVICETREE", True).split(" ")
+        dtbs = [os.path.splitext(os.path.basename(d)) for d in dtbs]
+        dtbs = ["%s.dtb" % name for name, ext in dtbs if ext == ".dts" or ext == ".dtb"]
+        return dtbs[0] if dtbs else ""
+    elif d.getVar("KERNEL_DEVICETREE", True):
+        dtbs = d.getVar("KERNEL_DEVICETREE", True).split(" ")
+        dtbs = [os.path.basename(d) for d in dtbs]
+        return d.getVar("KERNEL_IMAGETYPE", True) + "-" + (dtbs[0] if dtbs else "")
+    return ""
+
+def qemu_default_serial(d):
+    if d.getVar("SERIAL_CONSOLE", True):
+        speed, console = d.getVar("SERIAL_CONSOLE", True).split(" ", 1)
+        return "console=%s,%s earlyprintk" % (console, speed)
+    return ""
+
+def qemu_target_binary(d):
+    ta = d.getVar("TARGET_ARCH", True)
+    if ta == "microblazeeb":
+        ta = "microblaze"
+    elif ta == "arm":
+        ta = "aarch64"
+    return "qemu-system-%s" % ta
+
+# For runqemu, default setup across all machines in meta-xilinx
+IMAGE_CLASSES += "qemuboot"
+QB_SYSTEM_NAME ?= "${@qemu_target_binary(d)}"
+QB_DEFAULT_FSTYPE ?= "cpio"
+QB_DTB ?= "${@qemu_default_dtb(d)}"
+QB_KERNEL_CMDLINE_APPEND ?= "${@qemu_default_serial(d)}"
+

conf/machine/include/microblaze/feature-microblaze-barrel-shift.inc

@@ -0,0 +1,3 @@
+TUNEVALID[barrel-shift] = "Enable Microblaze Hardware Barrel Shift."
+MBCCARGSBARRELSHIFT += "${@bb.utils.contains("TUNE_FEATURES", "barrel-shift", "-mxl-barrel-shift", "-mno-xl-barrel-shift" ,d)}"
+MBPKGBARRELSHIFT .= "${@bb.utils.contains("TUNE_FEATURES", "barrel-shift", "-bs", "" ,d)}"

conf/machine/include/microblaze/feature-microblaze-divide.inc

@@ -0,0 +1,3 @@
+TUNEVALID[divide-hard] = "Enable Microblaze hardware divider."
+MBCCARGSDIV += "${@bb.utils.contains("TUNE_FEATURES", "divide-hard", "-mno-xl-soft-div", "-mxl-soft-div" ,d)}"
+MBPKGDIV .= "${@bb.utils.contains("TUNE_FEATURES", "divide-hard", "-div", "" ,d)}"

conf/machine/include/microblaze/feature-microblaze-endian.inc

@@ -0,0 +1,13 @@
+# This feature file must be included/required FIRST as it defines the start of the PKGARCH bitbake variable
+MBCCARGSENDIAN = ""
+MBPKGENDIAN = ""
+
+TUNEVALID[little-endian] = "Use Microblaze Little Endian."
+MBCCARGSENDIAN += "${@bb.utils.contains("TUNE_FEATURES", "little-endian", "-mlittle-endian", "" ,d)}"
+MBPKGENDIAN .= "${@bb.utils.contains("TUNE_FEATURES", "little-endian", "el", "" ,d)}"
+
+TUNEVALID[big-endian] = "Use Microblaze Big Endian."
+MBCCARGSENDIAN += "${@bb.utils.contains("TUNE_FEATURES", "big-endian", "-mbig-endian", "" ,d)}"
+MBPKGENDIAN .= "${@bb.utils.contains("TUNE_FEATURES", "big-endian", "eb", "" ,d)}"
+
+TUNECONFLICTS[little-endian] = "big-endian"

conf/machine/include/microblaze/feature-microblaze-fpu.inc

@@ -0,0 +1,17 @@
+TUNEVALID[fpu-soft] = "Use Microblaze software FPU"
+TUNEVALID[fpu-hard] = "Enable Microblaze hardware FPU in basic mode."
+TUNEVALID[fpu-hard-extended] = "Enable Microblaze hardware FPU in extended mode - conversion and square root instructions."
+
+# Establish which fpu is configured in TUNE_FEATURES. Soft is the default for gcc.
+MBCCARGSFPU_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard", "-mhard-float", "", d)}"
+MBCCARGSFPU = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard-extended", "-mhard-float -mxl-float-convert -mxl-float-sqrt", "${MBCCARGSFPU_BASIC}" ,d)}"
+
+MBPKGFPU_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard", "-fb", "", d)}"
+MBPKGFPU = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard-extended", "-fe", "${MBPKGFPU_BASIC}", d)}"
+
+# Set target fpu (bitbake known target) to soft or hard (basic or extended in microblaze language)
+TARGETFPU_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard", "fpu-hard", "fpu-soft", d)}"
+TARGET_FPU = "${@bb.utils.contains("TUNE_FEATURES", "fpu-hard-extended", "fpu-hard", "${TARGETFPU_BASIC}", d)}"
+
+TUNECONFLICTS[fpu-hard] = "fpu-soft"
+TUNECONFLICTS[fpu-hard-extended] = "fpu-soft"

conf/machine/include/microblaze/feature-microblaze-multiply.inc

@@ -0,0 +1,9 @@
+TUNEVALID[multiply-low] = "Enable Microblaze Hardware Multiply with low (32 bit) result."
+TUNEVALID[multiply-high] = "Enable Microblaze Hardware Multiply with high (64 bit) result."
+
+# Establish which Multiply output result size to use
+MBCCARGSMUL_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "multiply-low", "-mno-xl-soft-mul", "-mxl-soft-mul" ,d)}"
+MBCCARGSMUL = "${@bb.utils.contains("TUNE_FEATURES", "multiply-high", "-mno-xl-soft-mul -mxl-multiply-high", "${MBCCARGSMUL_BASIC}" ,d)}"
+
+MBPKGMUL_BASIC = "${@bb.utils.contains("TUNE_FEATURES", "multiply-low", "-ml", "" ,d)}"
+MBPKGMUL = "${@bb.utils.contains("TUNE_FEATURES", "multiply-high", "-mh", "${MBPKGMUL_BASIC}" ,d)}"

conf/machine/include/microblaze/feature-microblaze-pattern-compare.inc

@@ -0,0 +1,3 @@
+TUNEVALID[pattern-compare] = "Enable Microblaze Pattern Compare Instructions."
+MBCCARGSPATTERNCOMPARE = "${@bb.utils.contains("TUNE_FEATURES", "pattern-compare", "-mxl-pattern-compare", "-mno-xl-pattern-compare" ,d)}"
+MBPKGSPATTERNCOMPARE = "${@bb.utils.contains("TUNE_FEATURES", "pattern-compare", "-cmp", "" ,d)}"

conf/machine/include/microblaze/feature-microblaze-reorder.inc

@@ -0,0 +1,3 @@
+TUNEVALID[reorder] = "Enable Microblaze Reorder Instructions."
+MBCCARGSREORDER = "${@bb.utils.contains("TUNE_FEATURES", "reorder", "-mxl-reorder", "-mno-xl-reorder" ,d)}"
+MBPKGREORDER = "${@bb.utils.contains("TUNE_FEATURES", "reorder", "-re", "" ,d)}"

conf/machine/include/microblaze/feature-microblaze-v10.inc

@@ -0,0 +1,5 @@
+# Setup version 'feature set' for supported Microblaze version 10 versions
+
+TUNEVALID[v10.0] = "Use Microblaze version 10.0"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v10.0", "-mcpu=v10.0", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v10.0", "-v10.0", "" ,d)}"

conf/machine/include/microblaze/feature-microblaze-v7.inc

@@ -0,0 +1,7 @@
+# Setup version 'feature set' for supported Microblaze version 7 versions
+TUNEVALID[v7.30] = "Use Microblaze version 7.30"
+
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v7.30", "-mcpu=v7.30.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v7.30", "-v7.30", "" ,d)}"
+
+TUNECONFLICTS[v7.30] += "reorder little-endian"

conf/machine/include/microblaze/feature-microblaze-v8.inc

@@ -0,0 +1,45 @@
+# Setup version 'feature set' for supported Microblaze version 8 versions
+TUNEVALID[v8.50] = "Use Microblaze version 8.50"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.50", "-mcpu=v8.50.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.50", "-v8.50", "" ,d)}"
+
+TUNEVALID[v8.40] = "Use Microblaze version 8.40"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.40", "-mcpu=v8.40.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.40", "-v8.40", "" ,d)}"
+
+TUNEVALID[v8.30] = "Use Microblaze version 8.30"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.30", "-mcpu=v8.30.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.30", "-v8.30", "" ,d)}"
+
+TUNEVALID[v8.20] = "Use Microblaze version 8.20"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.20", "-mcpu=v8.20.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.20", "-v8.20", "" ,d)}"
+
+TUNEVALID[v8.10] = "Use Microblaze version 8.10"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.10", "-mcpu=v8.10.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.10", "-v8.10", "" ,d)}"
+
+TUNEVALID[v8.00] = "Use Microblaze version 8.00"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v8.00", "-mcpu=v8.00.a", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v8.00", "-v8.00", "" ,d)}"
+
+TUNECONFLICTS[v8.00] += "reorder"
+TUNECONFLICTS[v8.10] += "reorder"
+TUNECONFLICTS[v8.20] += "reorder"
+
+# Perform some additional sanity checking
+python __anonymous () {
+    import bb
+    tune_features = bb.data.getVar('TUNE_FEATURES', d, 1)
+    tuneslist = tune_features.split()
+
+    #
+    # GCC will fail on v8.30 if reorder and pattern-compare are not 
+    # both in ccflags
+    # -mxl-reorder requires -mxl-pattern-compare for -mcpu=v8.30.a
+    # Check if either one exists alone and if so, add the other
+    #
+    if 'v8.30' in tuneslist:
+        if 'reorder' in tuneslist and 'pattern-compare' not in tuneslist:
+            d.setVar("TUNE_FEATURES", "%s pattern-compare" % tune_features)
+}

conf/machine/include/microblaze/feature-microblaze-v9.inc

@@ -0,0 +1,8 @@
+# Setup version 'feature set' for supported Microblaze version 9 versions
+TUNEVALID[v9.6] = "Use Microblaze version 9.6"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v9.6", "-mcpu=v9.6", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v9.6", "-v9.6", "" ,d)}"
+
+TUNEVALID[v9.0] = "Use Microblaze version 9.0"
+MBCCARGSVERSION += "${@bb.utils.contains("TUNE_FEATURES", "v9.0", "-mcpu=v9.0", "" ,d)}"
+MBPKGVERSION .= "${@bb.utils.contains("TUNE_FEATURES", "v9.0", "-v9.0", "" ,d)}"

conf/machine/include/microblaze/feature-microblaze-versions.inc

@@ -0,0 +1,22 @@
+# Microblaze Versions are defined as features sets, each containing 
+# a set of hardware features.
+
+MBCCARGSVERSION = ""
+MBPKGVERSION = ""
+require conf/machine/include/microblaze/feature-microblaze-v10.inc
+require conf/machine/include/microblaze/feature-microblaze-v9.inc
+require conf/machine/include/microblaze/feature-microblaze-v8.inc
+require conf/machine/include/microblaze/feature-microblaze-v7.inc
+
+# Setup a 'feature set' conflict list which ensures only one version is selected
+# when defining the TUNE_FEATURES_tune-<>  in local.conf file.
+TUNECONFLICTS[v10.0] += "v7.30 v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.6"
+TUNECONFLICTS[v9.6]  += "v7.30 v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v10.0"
+TUNECONFLICTS[v9.0]  += "v7.30 v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.6 v10.0"
+TUNECONFLICTS[v8.50] += "v7.30 v8.00 v8.10 v8.20 v8.30 v8.40 v9.0 v9.6 v10.0"
+TUNECONFLICTS[v8.40] += "v7.30 v8.00 v8.10 v8.20 v8.30 v8.50 v9.0 v9.6 v10.0"
+TUNECONFLICTS[v8.30] += "v7.30 v8.00 v8.10 v8.20 v8.40 v8.50 v9.0 v9.6 v10.0"
+TUNECONFLICTS[v8.20] += "v7.30 v8.00 v8.10 v8.30 v8.40 v8.50 v9.0 v9.6 v10.0"
+TUNECONFLICTS[v8.10] += "v7.30 v8.00 v8.20 v8.30 v8.40 v8.50 v9.0 v9.6 v10.0"
+TUNECONFLICTS[v8.00] += "v7.30 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.6 v10.0"
+TUNECONFLICTS[v7.30] += "v8.00 v8.10 v8.20 v8.30 v8.40 v8.50 v9.0 v9.6 v10.0"

conf/machine/include/tune-microblaze-features.inc

@@ -0,0 +1,20 @@
+# The order of these files defines the order of sections in the PKGARCH variable
+require conf/machine/include/microblaze/feature-microblaze-endian.inc
+require conf/machine/include/microblaze/feature-microblaze-versions.inc
+require conf/machine/include/microblaze/feature-microblaze-barrel-shift.inc
+require conf/machine/include/microblaze/feature-microblaze-multiply.inc
+require conf/machine/include/microblaze/feature-microblaze-divide.inc
+require conf/machine/include/microblaze/feature-microblaze-fpu.inc
+require conf/machine/include/microblaze/feature-microblaze-pattern-compare.inc
+require conf/machine/include/microblaze/feature-microblaze-reorder.inc
+
+# Architecture name, either 'microblaze' or 'microblazeel' depending on endianess
+TUNE_ARCH = "microblaze${@bb.utils.contains("TUNE_FEATURES", "little-endian", "el", "eb" ,d)}"
+
+# Compiler args
+TUNE_CCARGS += "${MBCCARGSENDIAN} ${MBCCARGSVERSION} ${MBCCARGSBARRELSHIFT} ${MBCCARGSMUL} ${MBCCARGSDIV} ${MBCCARGSFPU} ${MBCCARGSPATTERNCOMPARE} ${MBCCARGSREORDER}"
+
+# Package Architecture formatting
+MBPKGMATH = "${MBPKGMUL}${MBPKGDIV}${MBPKGFPU}"
+TUNE_PKGARCH = "microblaze${MBPKGENDIAN}${MBPKGVERSION}${MBPKGBARRELSHIFT}${MBPKGSPATTERNCOMPARE}${MBPKGREORDER}${MBPKGMATH}"
+

conf/machine/include/tune-microblaze.inc

@@ -0,0 +1,27 @@
+DEFAULTTUNE ?= "microblaze"
+
+require conf/machine/include/tune-microblaze-features.inc
+
+TUNEVALID[microblaze] = "Microblaze"
+AVAILTUNES += "microblaze"
+
+TUNE_FEATURES_tune-microblaze = "microblaze"
+PACKAGE_EXTRA_ARCHS_tune-microblaze = "${TUNE_PKGARCH}"
+
+# override for architecture
+MACHINEOVERRIDES =. "${@bb.utils.contains("TUNE_FEATURES", "microblaze", "microblaze:", "" ,d)}"
+
+# Linux Configuration
+KERNEL_IMAGETYPE ?= "linux.bin.ub"
+
+# U-Boot Configuration
+UBOOT_MACHINE ?= "microblaze-generic_config"
+
+# linux-yocto KMACHINE
+KMACHINE ?= "microblaze"
+
+# default to use the gdb 7.7.1
+PREFERRED_VERSION_gdb ?= "7.7.1"
+PREFERRED_VERSION_gdb-cross ?= "7.7.1"
+PREFERRED_VERSION_gdb-cross-canadian ?= "7.7.1"
+

conf/machine/include/tune-zynq.inc

@@ -0,0 +1,15 @@
+DEFAULTTUNE ?= "cortexa9thf-neon"
+SOC_FAMILY ?= "zynq"
+
+require conf/machine/include/tune-cortexa9.inc
+require conf/machine/include/soc-family.inc
+
+# Linux Configuration
+KERNEL_IMAGETYPE ?= "uImage"
+
+# Set default load address.
+# Override with KERNEL_EXTRA_ARGS_<board> += "..." in machine file if required
+KERNEL_EXTRA_ARGS_zynq += "UIMAGE_LOADADDR=0x8000"
+
+# KMACHINE
+KMACHINE ?= "zynq"

conf/machine/include/tune-zynqmp.inc

@@ -0,0 +1,12 @@
+DEFAULTTUNE ?= "aarch64"
+SOC_FAMILY ?= "zynqmp"
+
+require conf/machine/include/arm/arch-armv8.inc
+require conf/machine/include/soc-family.inc
+
+# Linux Configuration
+KERNEL_IMAGETYPE ?= "Image"
+
+# KMACHINE
+KMACHINE ?= "zynqmp"
+

conf/machine/zturn-zynq7.conf

@@ -0,0 +1,20 @@
+#@TYPE: Machine
+#@NAME: zturn-zynq7
+#@DESCRIPTION: Machine support for Z-Turn.
+
+require conf/machine/include/tune-zynq.inc
+require conf/machine/include/machine-xilinx-default.inc
+require conf/machine/include/machine-xilinx-board.inc
+
+MACHINE_FEATURES = "ext2 vfat usbhost usbgadget"
+
+# u-boot configuration
+UBOOT_MACHINE = "zynq_zturn_config"
+SPL_BINARY = "boot.bin"
+
+SERIAL_CONSOLE = "115200 ttyPS0"
+
+KERNEL_DEVICETREE = "zynq-zturn.dtb zynq-zturn-xylon.dtb"
+
+IMAGE_BOOT_FILES += "boot.bin ${KERNEL_IMAGETYPE}-zynq-zturn.dtb ${KERNEL_IMAGETYPE}-zynq-zturn-xylon.dtb"
+