Add a simple website

.github/workflows/buildsite.yml

@@ -0,0 +1,56 @@
+name: Generate web page
+
+on:
+  push:
+    branches: 'main'
+  workflow_dispatch:
+
+jobs:
+  build:
+    runs-on: ubuntu-latest
+    container: perl:latest
+
+    steps:
+    - name: Perl version
+      run: perl -v
+
+    - name: Checkout
+      uses: actions/checkout@v4
+
+    - name: Install pandoc and cpanm
+      run: apt-get update && apt-get install -y pandoc cpanminus
+
+    - name: Install modules
+      run: |
+        cpanm --installdeps --notest .
+
+    - name: Get repo name into environment
+      run: |
+        echo "REPO_NAME=${GITHUB_REPOSITORY#$GITHUB_REPOSITORY_OWNER/}" >> $GITHUB_ENV
+
+    - name: Create pages
+      env:
+        PERL5LIB: lib
+        GITHUB_TOKEN: ${{ secrets.GITHUB_TOKEN }}
+      run: |
+        mkdir -p web
+        perl bin/build $REPO_NAME
+
+    - name: Update pages artifact
+      uses: actions/upload-pages-artifact@v3
+      with:
+        path: web/
+
+  deploy:
+    needs: build
+    permissions:
+      pages: write
+      id-token: write
+    environment:
+      name: github-pages
+      url: ${{ steps.deployment.outputs.page_url }}
+    runs-on: ubuntu-latest
+    steps:
+      - name: Deploy to GitHub Pages
+        id: deployment
+        uses: actions/deploy-pages@v4

.gitignore

@@ -0,0 +1 @@
+web/

bin/build

@@ -0,0 +1,83 @@
+#!/usr/bin/perl
+
+use strict;
+use warnings;
+
+use v5.38;
+use File::Copy;
+use JSON;
+use Template;
+use Template::Provider::Pandoc;
+
+use PPC;
+
+my @ppcs;
+my %status;
+
+my $outpath = './web';
+my $template_path = [ './ppcs', './docs', './in', './ttlib' ];
+
+my $base = shift || $outpath;
+$base =~ s/^\.//;
+$base = "/$base" if $base !~ m|^/|;
+$base = "$base/" if $base !~ m|/$|;
+
+my $provider = Template::Provider::Pandoc->new({
+  INCLUDE_PATH => $template_path,
+});
+
+my $tt = Template->new({
+  LOAD_TEMPLATES => [ $provider ],
+  INCLUDE_PATH => $template_path,
+  OUTPUT_PATH => $outpath,
+  RELATIVE => 1,
+  WRAPPER => 'page.tt',
+  VARIABLES => {
+    base => $base,
+  }
+});
+
+for (<ppcs/*.md>) {
+  my $ppc = PPC->new_from_file($_);
+  push @ppcs, $ppc;
+
+  $tt->process($ppc->in_path, {}, $ppc->out_path)
+    or warn $tt->error;
+}
+
+my $vars = {
+  ppcs => \@ppcs,
+};
+
+$tt->process('index.tt', $vars, 'index.html')
+  or die $tt->error;
+
+for (<docs/*.md>) {
+  s|^docs/||;
+  my $out = s|\.md|/index.html|r;
+
+  $tt->process($_, {}, $out)
+    or die $tt->error;
+}
+
+mkdir 'web/images';
+for (<images/*>) {
+  copy $_, "web/$_";
+}
+
+if (-f 'in/style.css') {
+  copy 'in/style.css', 'web/style.css';
+}
+
+if (-f 'CNAME') {
+  copy 'CNAME', "web/CNAME";
+}
+
+my $json = JSON->new->pretty->canonical->encode([
+  map { $_->as_data } @ppcs
+]);
+
+open my $json_fh, '>', 'web/ppcs.json' or die $!;
+
+print $json_fh $json;
+

cpanfile

@@ -0,0 +1,4 @@
+requires 'File::Copy';
+requires 'JSON';
+requires 'Template';
+requires 'Template::Provider::Pandoc';

docs/process.md

@@ -21,7 +21,7 @@ Hence we need a process that
 We'd like to record proposals to improve the language and their status as "Request For Comment" documents in their own repository under the Perl organisation on GitHub.
 
 
-We have a [template](template.md) for what an completed implemented PPC should end up as, but if all you have is an idea - don't worry, we'll help you get there.  We're still figuring this process out, so for now we're doing it as mail messages sent to p5p, not as "pull requests" to the PPC repository (or "issues" on the source repository). This way we can see if the process works as hoped, and fix the parts that don't.
+We have a [template](./template.md) for what an completed implemented PPC should end up as, but if all you have is an idea - don't worry, we'll help you get there.  We're still figuring this process out, so for now we're doing it as mail messages sent to p5p, not as "pull requests" to the PPC repository (or "issues" on the source repository). This way we can see if the process works as hoped, and fix the parts that don't.
 
 
 ## What makes a good idea?
@@ -46,7 +46,7 @@ Not every good idea belongs in the Perl core. Some are better implemented on CPA
 
 ## The Process
 
-![a flowchart of the process described below](/images/flowchart.png)
+![a flowchart of the process described below](./images/flowchart.png)
 
 
 ### Pre-PPC
@@ -63,7 +63,7 @@ During this phase, you (the proposer) are responsible for moving things forward.
 
 ### Draft Proposal
 
-The PSC has agreed that you should write a formal draft proposal.  You get the [template document](template.md) and fill it out.  You take its advice, thinking hard about what goes in each section.  Then you post it to p5p as an email with the subject "PROPOSAL:  my great idea".  Members of the list will reply with more questions and suggested amendments.  You should read them and amend the proposal to clarify your ideas or react to valid criticism.
+The PSC has agreed that you should write a formal draft proposal.  You get the [template document](./template.md) and fill it out.  You take its advice, thinking hard about what goes in each section.  Then you post it to p5p as an email with the subject "PROPOSAL:  my great idea".  Members of the list will reply with more questions and suggested amendments.  You should read them and amend the proposal to clarify your ideas or react to valid criticism.
 
 During this phase, you (the proposer) are responsible for moving things
 forward.

in/index.tt

@@ -0,0 +1,37 @@
+<h1>Proposed Perl Changes</h1>
+
+<p>Welcome to the Proposed Perl Changes web site.</p>
+
+<p>Download this data as <a href="./ppcs.json">JSON</a>.</p>
+<table class="table" id="datatable">
+  <thead>
+    <tr>
+      <th>ID</th>
+      <th>Title</th>
+      <th>Status</th>
+      <th>Author(s)</th>
+      <th>Sponsor</th>
+    </tr>
+  </thead>
+  <tbody>
+[% FOR ppc IN ppcs -%]
+    <tr>
+      <td>[% ppc.id | html %]</td>
+      <td><a href="./[% ppc.slug %]/">[% ppc.title | html %]</a></td>
+      <td>[% ppc.status | html %]</td>
+      <td>[% ppc.author | html %]</td>
+      <td>[% ppc.sponsor | html %]</td>
+    </tr>
+[% END -%]
+  </tbody>
+</table>
+
+<script>
+  window.dt = new window.simpleDatatables.DataTable("#datatable", {
+    perPageSelect: [5, 10, 15, ["All", -1]],
+    columns: [{
+      select: 0,
+      type: "numeric"
+    }]
+  });
+</script>

in/style.css

@@ -0,0 +1,3 @@
+main > .container {
+  padding: 60px 15px 0;
+}

lib/PPC.pm

@@ -0,0 +1,80 @@
+use experimental qw[builtin class signatures];
+
+class PPC;
+
+use builtin 'trim';
+
+field $author  :param = '';
+field $id      :param;
+field $slug    :param;
+field $sponsor :param = '';
+field $status  :param;
+field $title   :param;
+
+method author  { return $author }
+method id      { return $id }
+method slug    { return $slug }
+method sponsor { return $sponsor }
+method status  { return $status }
+method title  { return $title }
+
+method in_path {
+  return "$slug.md";
+}
+
+method out_path {
+  return "$slug/index.html";
+}
+
+method as_data {
+  return {
+    id      => $id,
+    status  => $status,
+    author  => $author,
+    sponsor => $sponsor,
+    slug    => $slug,
+    title   => $title,
+  };
+}
+
+# Very hacky parser
+
+sub new_from_file($class, $ppc_file) {
+
+  open my $ppc_fh, '<', $ppc_file
+    or warn "Cannot open PPC [$_]: $!\n" and return;
+
+  my (%ppc, $is_preamble);
+
+  $ppc{slug} = $ppc_file;
+  $ppc{slug} =~ s|^ppcs/||;
+  $ppc{slug} =~ s|\.md$||;
+
+  while (<$ppc_fh>) {
+    $. == 1 and m|#\s+(.*)| and $ppc{title} = $1;
+
+    $is_preamble and /## abstract/i and last;
+
+    $_ = trim($_);
+
+    if ($is_preamble and $_) {
+
+      my ($key, $value) = split(/\s*:\s*/, $_, 2);
+
+      $ppc{lc $key} = $value;
+    }
+
+    # 'pre.+mble' because Paul likes to use 'Preämble'
+    /## pre.+mble/i and $is_preamble = 1;
+  }
+
+  if (exists $ppc{authors}) {
+    $ppc{author} = delete $ppc{authors}
+  }
+
+  $ppc{$_} =~ s|\@.+?>|\@XXXX>|g for (qw[author sponsor]);
+
+  return $class->new(%ppc);
+}
+
+1;