Add lib/compatibility.bzl

README.md

@@ -43,6 +43,7 @@ s = shell.quote(p)
 ## List of modules (in lib/)
 
 * [collections](docs/collections_doc.md)
+* [compatibility](docs/compatibility_doc.md)
 * [dicts](docs/dicts_doc.md)
 * [partial](docs/partial_doc.md)
 * [paths](docs/paths_doc.md)

docs/BUILD

@@ -22,6 +22,11 @@ stardoc_with_diff_test(
     out_label = "//docs:common_settings_doc.md",
 )
 
+stardoc_with_diff_test(
+    bzl_library_target = "//lib:compatibility",
+    out_label = "//docs:compatibility_doc.md",
+)
+
 stardoc_with_diff_test(
     bzl_library_target = "//rules:copy_directory",
     out_label = "//docs:copy_directory_doc.md",

docs/compatibility_doc.md

@@ -0,0 +1,145 @@
+<!-- Generated with Stardoc: http://skydoc.bazel.build -->
+
+Skylib module of convenience functions for `target_compatible_with`.
+
+Load the macros as follows in your `BUILD` files:
+```python
+load("@bazel_skylib//lib:compatibility.bzl", "compatibility")
+```
+
+See the [Platform docs](https://bazel.build/docs/platforms#skipping-incompatible-targets) for
+more information.
+
+
+<a id="#compatibility.all_of"></a>
+
+## compatibility.all_of
+
+<pre>
+compatibility.all_of(<a href="#compatibility.all_of-settings">settings</a>)
+</pre>
+
+Create a `select()` for `target_compatible_with` which matches all of the given settings.
+
+All of the settings must be true to get an empty list. Failure to match will result
+in an incompatible `constraint_value` for the purpose of target skipping.
+
+In other words, use this function to make a target incompatible unless all of the settings are
+true.
+
+Example:
+
+```python
+config_setting(
+    name = "dbg",
+    values = {"compilation_mode": "dbg"},
+)
+
+cc_binary(
+    name = "bin",
+    srcs = ["bin.cc"],
+    # This target can only be built for Linux in debug mode.
+    target_compatible_with = compatibility.all_of(
+        ":dbg",
+        "@platforms//os:linux",
+    ),
+)
+```
+
+See also: `selects.config_setting_group(match_all)`
+
+
+**PARAMETERS**
+
+
+| Name  | Description | Default Value |
+| :------------- | :------------- | :------------- |
+| <a id="compatibility.all_of-settings"></a>settings |  The <code>config_setting</code> or <code>constraint_value</code> targets.   |  none |
+
+**RETURNS**
+
+A native series of `select()`s. The result is "incompatible" unless all settings are true.
+
+
+<a id="#compatibility.any_of"></a>
+
+## compatibility.any_of
+
+<pre>
+compatibility.any_of(<a href="#compatibility.any_of-settings">settings</a>)
+</pre>
+
+Create a `select()` for `target_compatible_with` which matches any of the given settings.
+
+Any of the settings will resolve to an empty list, while the default condition will map to
+an incompatible `constraint_value` for the purpose of target skipping.
+
+In other words, use this function to make target incompatible unless one or more of the
+settings are true.
+
+```python
+cc_binary(
+    name = "bin",
+    srcs = ["bin.cc"],
+    # This target can only be built for Linux or Mac.
+    target_compatible_with = compatibility.any_of(
+        "@platforms//os:linux",
+        "@platforms//os:macos",
+    ),
+)
+```
+
+
+**PARAMETERS**
+
+
+| Name  | Description | Default Value |
+| :------------- | :------------- | :------------- |
+| <a id="compatibility.any_of-settings"></a>settings |  The <code>config_settings</code> or <code>constraint_value</code> targets.   |  none |
+
+**RETURNS**
+
+A native `select()` which maps any of the settings an empty list.
+
+
+<a id="#compatibility.none_of"></a>
+
+## compatibility.none_of
+
+<pre>
+compatibility.none_of(<a href="#compatibility.none_of-settings">settings</a>)
+</pre>
+
+Create a `select()` for `target_compatible_with` which matches none of the given settings.
+
+Any of the settings will resolve to an incompatible `constraint_value` for the
+purpose of target skipping.
+
+In other words, use this function to make target incompatible if any of the settings are true.
+
+```python
+cc_binary(
+    name = "bin",
+    srcs = ["bin.cc"],
+    # This target cannot be built for Linux or Mac, but can be built for
+    # everything else.
+    target_compatible_with = compatibility.none_of(
+        "@platforms//os:linux",
+        "@platforms//os:macos",
+    ),
+)
+```
+
+
+**PARAMETERS**
+
+
+| Name  | Description | Default Value |
+| :------------- | :------------- | :------------- |
+| <a id="compatibility.none_of-settings"></a>settings |  The <code>config_setting</code> or <code>constraint_value</code> targets.   |  none |
+
+**RETURNS**
+
+A native `select()` which maps any of the settings to the incompatible target.
+
+

lib/BUILD

@@ -15,6 +15,15 @@ bzl_library(
     srcs = ["collections.bzl"],
 )
 
+bzl_library(
+    name = "compatibility",
+    srcs = ["compatibility.bzl"],
+    deps = [
+        ":selects",
+        "//lib/compatibility:defs",
+    ],
+)
+
 bzl_library(
     name = "dicts",
     srcs = ["dicts.bzl"],

lib/compatibility.bzl

@@ -0,0 +1,130 @@
+"""Skylib module of convenience functions for `target_compatible_with`.
+
+Load the macros as follows in your `BUILD` files:
+```python
+load("@bazel_skylib//lib:compatibility.bzl", "compatibility")
+```
+
+See the [Platform docs](https://bazel.build/docs/platforms#skipping-incompatible-targets) for
+more information.
+"""
+
+load(":selects.bzl", "selects")
+load("//lib/compatibility:defs.bzl", "MAX_NUM_ALL_OF_SETTINGS")
+
+def _none_of(*settings):
+    """Create a `select()` for `target_compatible_with` which matches none of the given settings.
+
+    Any of the settings will resolve to an incompatible `constraint_value` for the
+    purpose of target skipping.
+
+    In other words, use this function to make target incompatible if any of the settings are true.
+
+    ```python
+    cc_binary(
+        name = "bin",
+        srcs = ["bin.cc"],
+        # This target cannot be built for Linux or Mac, but can be built for
+        # everything else.
+        target_compatible_with = compatibility.none_of(
+            "@platforms//os:linux",
+            "@platforms//os:macos",
+        ),
+    )
+    ```
+
+    Args:
+      *settings: The `config_setting` or `constraint_value` targets.
+
+    Returns:
+      A native `select()` which maps any of the settings to the incompatible target.
+    """
+    return selects.with_or({
+        "//conditions:default": [],
+        tuple(settings): ["@bazel_skylib//lib/compatibility:none_of"],
+    })
+
+def _any_of(*settings):
+    """Create a `select()` for `target_compatible_with` which matches any of the given settings.
+
+    Any of the settings will resolve to an empty list, while the default condition will map to
+    an incompatible `constraint_value` for the purpose of target skipping.
+
+    In other words, use this function to make target incompatible unless one or more of the
+    settings are true.
+
+    ```python
+    cc_binary(
+        name = "bin",
+        srcs = ["bin.cc"],
+        # This target can only be built for Linux or Mac.
+        target_compatible_with = compatibility.any_of(
+            "@platforms//os:linux",
+            "@platforms//os:macos",
+        ),
+    )
+    ```
+
+    Args:
+      *settings: The `config_settings` or `constraint_value` targets.
+
+    Returns:
+      A native `select()` which maps any of the settings an empty list.
+    """
+    return selects.with_or({
+        tuple(settings): [],
+        "//conditions:default": ["@bazel_skylib//lib/compatibility:any_of"],
+    })
+
+def _all_of(*settings):
+    """Create a `select()` for `target_compatible_with` which matches all of the given settings.
+
+    All of the settings must be true to get an empty list. Failure to match will result
+    in an incompatible `constraint_value` for the purpose of target skipping.
+
+    In other words, use this function to make a target incompatible unless all of the settings are
+    true.
+
+    Example:
+
+    ```python
+    config_setting(
+        name = "dbg",
+        values = {"compilation_mode": "dbg"},
+    )
+
+    cc_binary(
+        name = "bin",
+        srcs = ["bin.cc"],
+        # This target can only be built for Linux in debug mode.
+        target_compatible_with = compatibility.all_of(
+            ":dbg",
+            "@platforms//os:linux",
+        ),
+    )
+    ```
+
+    See also: `selects.config_setting_group(match_all)`
+
+    Args:
+      *settings: The `config_setting` or `constraint_value` targets.
+
+    Returns:
+      A native series of `select()`s. The result is "incompatible" unless all settings are true.
+    """
+    if len(settings) > MAX_NUM_ALL_OF_SETTINGS:
+        fail("Cannot support more than {} arguments. Use selects.config_setting_group() instead.".format(MAX_NUM_ALL_OF_SETTINGS))
+
+    result = []
+    for i, setting in enumerate(settings):
+        result += select({
+            setting: [],
+            "//conditions:default": ["@bazel_skylib//lib/compatibility:all_of_{}".format(i)],
+        })
+    return result
+
+compatibility = struct(
+    all_of = _all_of,
+    any_of = _any_of,
+    none_of = _none_of,
+)

lib/compatibility/BUILD

@@ -0,0 +1,32 @@
+load(":defs.bzl", "MAX_NUM_ALL_OF_SETTINGS")
+load("//:bzl_library.bzl", "bzl_library")
+
+licenses(["notice"])
+
+package(default_visibility = ["//visibility:public"])
+
+bzl_library(
+    name = "defs",
+    srcs = ["defs.bzl"],
+)
+
+filegroup(
+    name = "build_file",
+    testonly = True,
+    srcs = ["BUILD"],
+)
+
+constraint_value(
+    name = "none_of",
+    constraint_setting = "@platforms//:incompatible_setting",
+)
+
+constraint_value(
+    name = "any_of",
+    constraint_setting = "@platforms//:incompatible_setting",
+)
+
+[constraint_value(
+    name = "all_of_" + str(i),
+    constraint_setting = "@platforms//:incompatible_setting",
+) for i in range(MAX_NUM_ALL_OF_SETTINGS)]

lib/compatibility/defs.bzl

@@ -0,0 +1,4 @@
+"""Implementation details for lib/compatibility.bzl."""
+
+# The maximum number of arguments we support for compatibility.all_of().
+MAX_NUM_ALL_OF_SETTINGS = 50

tests/BUILD

@@ -92,6 +92,20 @@ sh_test(
     tags = ["local"],
 )
 
+sh_test(
+    name = "compatibility_test",
+    srcs = ["compatibility_test.sh"],
+    data = [
+        ":unittest.bash",
+        "//lib:compatibility",
+        "//lib/compatibility:build_file",
+    ],
+    tags = ["local"],
+    deps = [
+        "@bazel_tools//tools/bash/runfiles",
+    ],
+)
+
 shell_args_test_gen(
     name = "shell_spawn_e2e_test_src",
 )