Linked Data sources

This page lists sources of linked data relevant to the MUC-3 dataset.

DBpedia SPARQL endpoint:

1. Get people in the Wikipedia Columbian drug traffickers category. The query returns each person's DBpedia URI, name and abstract. If there is an equivalent Wikidata URI, then it gets that too...

    select distinct ?person ?name ?abstract ?wikidata WHERE {
    
      ?person dct:subject dbc:Colombian_drug_traffickers.
      ?person rdfs:label ?name.
      ?person dbo:abstract ?abstract.
   
      OPTIONAL {   
        ?person owl:sameAs ?wikidata.
        FILTER (regex(str(?wikidata), 'wikidata.org'))
      }
    
      FILTER ( LANGMATCHES(LANG(?name), "en") && LANGMATCHES(LANG(?abstract), "en") )
    }
   

2. Asking for the same entities again, but this time with alternative names for the people in the category (exploiting Wikipedia's "redirect" pages):

    CONSTRUCT {
      ?person rdf:type schema:Person;
              schema:name ?name;
              schema:alternateName ?alternateName.
    }
    WHERE {
      ?person dct:subject dbc:Colombian_drug_traffickers;
              rdf:type dbo:Person;
              rdfs:label ?name.
   
      ?otherPage dbo:wikiPageRedirects ?person;
                 rdfs:label ?alternateName.
   
      FILTER ( LANGMATCHES(LANG(?name), "en") ).
      FILTER ( LANGMATCHES(LANG(?alternateName), "en") ).
    }
   

RDF/XML

FactForge SPARQL endpoint:

1. Terrorist incidents...

    PREFIX fb: <http://rdf.freebase.com/ns/>
    PREFIX ff: <http://factforge.net/>
    
    SELECT distinct ?event ?label
    WHERE {
        ?event rdf:type fb:base.terrorism.topic.
        ?event rdf:type fb:time.event.
        ?event rdfs:label|ff:preferredLabel  ?label
    }
   

Not very many, and mostly from DBpedia - but there are some relevant to MUC-3 (such as Avianca Flight 203)