Add BlockDefinition translation parser plugin

Since BlockDefinitions are generic Resources, Godot doesn't
automatically extract translatable strings from them. In order to do
that, we need to provide an EditorTranslationParserPlugin that extracts
the desired fields so they're included in a POT file.

addons/block_code/block_code_plugin.gd

@@ -12,6 +12,9 @@ static var block_code_button: Button
 const BlockInspectorPlugin := preload("res://addons/block_code/inspector_plugin/block_script_inspector.gd")
 var block_inspector_plugin: BlockInspectorPlugin
 
+const BlockTranslationParserPlugin := preload("res://addons/block_code/translation/parser.gd")
+var _tx_parser_plugin: BlockTranslationParserPlugin
+
 var editor_inspector: EditorInspector
 
 var _selected_block_code: BlockCode
@@ -41,6 +44,10 @@ func _enter_tree():
 	block_inspector_plugin = BlockInspectorPlugin.new()
 	add_inspector_plugin(block_inspector_plugin)
 
+	if not _tx_parser_plugin:
+		_tx_parser_plugin = BlockTranslationParserPlugin.new()
+	add_translation_parser_plugin(_tx_parser_plugin)
+
 	# Remove unwanted class nodes from create node
 	old_feature_profile = EditorInterface.get_current_feature_profile()
 
@@ -69,6 +76,7 @@ func script_window_requested(script: String):
 
 
 func _exit_tree():
+	remove_translation_parser_plugin(_tx_parser_plugin)
 	remove_inspector_plugin(block_inspector_plugin)
 
 	if block_code_button:

addons/block_code/translation/parser.gd

@@ -0,0 +1,40 @@
+@tool
+## BlockCode translation parser plugin.
+##
+## Extracts translatable strings from BlockCode resources. Currently only
+## BlockDefinition resources are handled.
+extends EditorTranslationParserPlugin
+
+const BLOCK_DEFINITION_SCRIPT_PATH := "res://addons/block_code/code_generation/block_definition.gd"
+
+# BlockDefinition properties for translation
+const block_def_tx_properties: Array[String] = [
+	"category",
+	"description",
+	"display_template",
+]
+
+
+func _get_recognized_extensions() -> PackedStringArray:
+	# BlockDefinition resources currently use the generic tres extension.
+	return ["tres"]
+
+
+func _resource_is_block_definition(resource: Resource) -> bool:
+	var script := resource.get_script()
+	if not script:
+		return false
+	return script.resource_path == BLOCK_DEFINITION_SCRIPT_PATH
+
+
+func _parse_file(path: String, msgids: Array[String], msgids_context_plural: Array[Array]) -> void:
+	# Only BlockDefinition resources are supported.
+	var res = ResourceLoader.load(path, "Resource")
+	if not res or not _resource_is_block_definition(res):
+		return
+	for prop in block_def_tx_properties:
+		var value: String = res.get(prop)
+		if value:
+			# For now just the messages are used. It might be better to provide
+			# context with msgids_context_plural to avoid conflicts.
+			msgids.append(value)