Fuzzy.io CoffeeScript Style Guide

This is the fuzzy.io style guide for the CoffeeScript programming language.

Inspiration

The details in this guide have been very heavily inspired by several existing style guides and other resources. In particular:

• [https://github.com/polarmobile/coffeescript-style-guide](CoffeeScript Style Guide): Originally forked from.
• PEP-8: Style Guide for Python Code
• Bozhidar Batsov's Ruby Style Guide
• Google's JavaScript Style Guide
• Common CoffeeScript Idioms
• Thomas Reynolds' CoffeeScript-specific Style Guide
• Jeremy Ashkenas' code review of Spine
• The CoffeeScript FAQ

Table of Contents

• The CoffeeScript Style Guide
  • Code Layout
    • Tabs or Spaces?
    • Maximum Line Length
    • Blank Lines
    • Trailing Whitespace
    • Optional Commas
    • Encoding
  • Module Imports
  • Whitespace in Expressions and Statements
  • Comments
    • Block Comments
    • Inline Comments
    • No Dead Code
  • Naming Conventions
  • Functions
  • Strings
  • Conditionals
  • Looping and Comprehensions
  • Extending Native Objects
  • Exceptions
  • Annotations
  • Classes
  • The Magic Number
  • Miscellaneous

## Code layout ### Tabs or Spaces?

Use spaces only, with 2 spaces per indentation level. Never mix tabs and spaces.

### Maximum Line Length

Limit all lines to a maximum of 79 characters.

### Blank Lines

Separate top-level function and class definitions with a single blank line.

Separate method definitions inside of a class with a single blank line.

Use a single blank line within the bodies of methods or functions in cases where this improves readability (e.g., for the purpose of delineating logical sections).

### Trailing Whitespace

Do not include trailing whitespace on any lines.

### Optional Commas

Avoid the use of commas before newlines when properties or elements of an Object or Array are listed on separate lines.

# Yes
foo = [
  'some'
  'string'
  'values'
]
bar:
  label: 'test'
  value: 87

# No
foo = [
  'some',
  'string',
  'values'
]
bar:
  label: 'test',
  value: 87

### Encoding

UTF-8 is the preferred source file encoding.

## Module Imports

If using a module system (CommonJS Modules, AMD, etc.), require statements should be placed on separate lines.

require 'lib/setup'
Backbone = require 'backbone'

These statements should be grouped in the following order:

1. Standard library imports (if a standard library exists)
2. Third party library imports
3. Local imports (imports specific to this application or library)

## Whitespace in Expressions and Statements

Avoid extraneous whitespace in the following situations:

• Immediately inside parentheses, brackets or braces

     ($ 'body') # Yes
     ( $ 'body' ) # No

• Immediately before a comma

     console.log x, y # Yes
     console.log x , y # No

Additional recommendations:

• Always surround these binary operators with a single space on either side

  • assignment: =

    • Note that this also applies when indicating default parameter value(s) in a function declaration

      test: (param = null) -> # Yes
      test: (param=null) -> # No

  • augmented assignment: +=, -=, etc.

  • comparisons: ==, <, >, <=, >=, unless, etc.

  • arithmetic operators: +, -, *, /, etc.

  • (Do not use more than one space around these operators)

       # Yes
       x = 1
       y = 1
       fooBar = 3
    
       # No
       x      = 1
       y      = 1
       fooBar = 3

## Comments

If modifying code that is described by an existing comment, update the comment such that it accurately reflects the new code. (Ideally, improve the code to obviate the need for the comment, and delete the comment entirely.)

The first word of the comment should be capitalized, unless the first word is an identifier that begins with a lower-case letter.

If a comment is short, the period at the end can be omitted.

### Block Comments

Block comments apply to the block of code that follows them.

Each line of a block comment starts with a # and a single space, and should be indented at the same level of the code that it describes.

Paragraphs inside of block comments are separated by a line containing a single #.

  # This is a block comment. Note that if this were a real block
  # comment, we would actually be describing the proceeding code.
  #
  # This is the second paragraph of the same block comment. Note
  # that this paragraph was separated from the previous paragraph
  # by a line containing a single comment character.

  init()
  start()
  stop()

### Inline Comments

Inline comments are placed on the line immediately above the statement that they are describing. If the inline comment is sufficiently short, it can be placed on the same line as the statement (separated by a single space from the end of the statement).

All inline comments should start with a # and a single space.

The use of inline comments should be limited, because their existence is typically a sign of a code smell.

Do not use inline comments when they state the obvious:

  # No
  x = x + 1 # Increment x

However, inline comments can be useful in certain scenarios:

  # Yes
  x = x + 1 # Compensate for border

### No Dead Code

It is often convenient when debugging to "comment out" code to test different paths. Do not check in lines or blocks of commented-out code.

We use a version control system, so we can see "the old way of doing it" using history commands.

Dead code impedes code readability. It makes it hard to refactor -- do you move the dead code version when you move the working version? It ages poorly; usually there are other changes that make it impossible to uncomment the code and have it "just work". Dead code implies a lack of confidence in the working code. Was the dead code "better" in some way? Why did we comment it out, then?

## Naming Conventions

Use camelCase (with a leading lowercase character) to name all variables, methods, and object properties.

Use CamelCase (with a leading uppercase character) to name all classes. (This style is also commonly referred to as PascalCase, CamelCaps, or CapWords, among other alternatives.)

(The official CoffeeScript convention is camelcase, because this simplifies interoperability with JavaScript. For more on this decision, see here.)

For constants, use all uppercase with underscores:

CONSTANT_LIKE_THIS

Methods and variables that are intended to be "private" should begin with a leading underscore:

_privateMethod: ->

## Functions

(These guidelines also apply to the methods of a class.)

When declaring a function that takes arguments, always use a single space after the closing parenthesis of the arguments list:

foo = (arg1, arg2) -> # Yes
foo = (arg1, arg2)-> # No

Do not use parentheses when declaring functions that take no arguments:

bar = -> # Yes
bar = () -> # No

Use defaults for optional parameters:

foo = (arg1, arg2 = "default value") ->

Sometimes a function has so many optional parameters that its declaration can't fit on a single 79-character line. In this case, use a splat to pack up all the optional parameters, and then unpack with destructuring assignment.

foo = (arg1, options...) ->
  [arg2, arg3, arg4, arg5, arg6] = options
  arg2 or= "default value 2"
  arg3 or= "default value 3"
  arg4 or= "default value 4"
  arg5 or= "default value 5"
  arg6 or= "default value 6"

In cases where method calls are being chained and the code does not fit on a single line, each call should be placed on a separate line and indented by one level (i.e., two spaces), with a leading ..

[1..3]
  .map((x) -> x * x)
  .concat([10..12])
  .filter((x) -> x < 11)
  .reduce((x, y) -> x + y)

When calling functions, choose to omit or include parentheses in such a way that optimizes for readability. Keeping in mind that "readability" can be subjective, the following examples demonstrate cases where parentheses have been omitted or included in a manner that the community deems to be optimal:

baz 12

brush.ellipse x: 10, y: 20 # Braces can also be omitted or included for readability

foo(4).bar(8)

obj.value(10, 20) / obj.value(20, 10)

print inspect value

new Tag(new Value(a, b), new Arg(c))

## Strings

Use string interpolation instead of string concatenation:

"this is an #{adjective} string" # Yes
"this is an " + adjective + " string" # No

Prefer single quoted strings ('') instead of double quoted ("") strings, unless features like string interpolation are being used for the given string.

## Conditionals

Favor unless over if for negative conditions.

Instead of using unless...else, use if...else:

  # Yes
  if true
    ...
  else
    ...

  # No
  unless false
    ...
  else
    ...

Multi-line if/else clauses should use indentation:

  # Yes
  if true
    ...
  else
    ...

  # No
  if true then ...
  else ...

## Looping and Comprehensions

Take advantage of comprehensions whenever possible:

  # Yes
  result = (item.name for item in array)

  # No
  results = []
  for item in array
    results.push item.name

To filter:

result = (item for item in array when item.name is "test")

To iterate over the keys and values of objects:

object = one: 1, two: 2
alert("#{key} = #{value}") for key, value of object

## Extending Native Objects

Do not modify native objects.

For example, do not modify Array.prototype to introduce Array#forEach.

## Exceptions

Do not suppress exceptions.

## Annotations

Use annotations when necessary to describe a specific action that must be taken against the indicated block of code.

Write the annotation on the line immediately above the code that the annotation is describing.

The annotation keyword should be followed by a colon and a space, and a descriptive note.

  # FIXME: The client's current state should *not* affect payload processing.
  resetClientState()
  processPayload()

If multiple lines are required by the description, indent subsequent lines with two spaces:

  # TODO: Ensure that the value returned by this call falls within a certain
  #   range, or throw an exception.
  analyze()

Annotation types:

• TODO: describe missing functionality that should be added at a later date
• FIXME: describe broken code that must be fixed
• OPTIMIZE: describe code that is inefficient and may become a bottleneck
• HACK: describe the use of a questionable (or ingenious) coding practice
• REVIEW: describe code that should be reviewed to confirm implementation

If a custom annotation is required, the annotation should be documented in the project's README.

## Classes

Use classes to organize code.

A module should contain only one main class. The class should be the main export of the module.

class Foo
  # ...

module.exports = Foo

Use CoffeeScript's class statement to declare classes. Use CoffeeScript syntax to declare members. Don't use Crockford classes where everything is declared in the constructor. It's OK if private members aren't really private.

## The Magic Number

A classic psychological paper "The Magical Number Seven, Plus or Minus Two" proposes that human beings can handle lists of about 7±2 items in short-term memory. Although later studies show that the principle is not universal, it is a convenient boundary for thinking about groups and hierarchies.

If a list of things gets longer than 7±2, consider breaking it up into a hierarchy of sub-lists.

This principle applies in a few ways.

If a class has more than 5-9 methods, consider re-factoring it into multiple classes.

If a function has more than 5-9 lines of code, consider grouping the code into helper functions, each of which is less than 5-9 lines long, and call those helper functions from your main function.

## Miscellaneous

and is preferred over &&.

or is preferred over ||.

is is preferred over ==.

isnt is preferred over !=.

not is preferred over !.

or= should be used when possible:

temp or= {} # Yes
temp = temp || {} # No

Prefer shorthand notation (::) for accessing an object's prototype:

Array::slice # Yes
Array.prototype.slice # No

Prefer @property over this.property.

return @property # Yes
return this.property # No

However, avoid the use of standalone @:

return this # Yes
return @ # No

Avoid return where not required, unless the explicit return increases clarity.

Use splats (...) when working with functions that accept variable numbers of arguments:

console.log args... # Yes

(a, b, c, rest...) -> # Yes

Variables or properties that can have an object as a value should either have a valid object as that value, or null.

jim = new Person()
jim.address = new Address() # Yes
jim.address = null # Yes
jim.address = false # No
jim.address = undefined # No
jim.address = '' # No
jim.address = {} # No