Adding nix flake (#32)

chore(nix):
- add flake
- add installation instruction

.envrc

@@ -0,0 +1 @@
+use flake

.gitignore

@@ -2,4 +2,8 @@
 /examples/target
 /examples/pastebin/upload
 .idea
-/tests/integration/__pycache__
+/tests/integration/__pycache__
+.direnv/
+
+# output of `nix build`
+result

README.md

@@ -110,6 +110,42 @@ cargo install bugstalker --no-default-features
 pacman -S bugstalker
 ```
 
+#### Nix package manager
+There's flake which you can use to start using it. Just [enable flakes](https://wiki.nixos.org/wiki/Flakes#Enable_flakes_temporarily)
+then you're able to use it with:
+```
+nix run github:godzie44/BugStalker
+```
+
+`bugstalker` also provides a package which you can include to your NixOS config.
+For example:
+
+<details>
+
+```nix
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
+    bugstalker.url = "github:godzie44/BugStalker";
+  };
+
+  outpus = {nixpkgs, bugstalker, ...}: {
+    nixosConfigurations.your_hostname = nixpkgs.lib.nixosSystem {
+      modules = [
+        ({...}: {
+          environment.systemPackages = [
+            # assuming your system runs on a x86-64 cpu
+            bugstalker.packages."x86_64-linux".default
+          ];
+        })
+      ];
+    };
+  };
+}
+```
+
+</details>
+
 ---
 
 ## Start debugger session

flake.nix

@@ -0,0 +1,42 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    rust-overlay.url = "github:oxalica/rust-overlay";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+  };
+
+  outputs = inputs@{ flake-parts, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; }
+      {
+        systems = [
+          "x86_64-linux"
+          "aarch64-linux"
+        ];
+
+        perSystem = { self', lib, system, pkgs, config, ... }: {
+          _module.args.pkgs = import inputs.nixpkgs {
+            inherit system;
+
+            overlays = with inputs; [
+              rust-overlay.overlays.default
+            ];
+          };
+
+          apps.default = {
+            type = "app";
+            program = self'.packages.default;
+          };
+
+          packages.default = pkgs.callPackage (import ./nix/package.nix) { };
+
+          devShells.default =
+            let
+              bs = self'.packages.default;
+              rust-toolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
+            in
+            pkgs.mkShell {
+              packages = [ rust-toolchain ] ++ bs.buildInputs ++ bs.nativeBuildInputs;
+            };
+        };
+      };
+}

nix/package.nix

@@ -0,0 +1,33 @@
+{ lib
+, rustPlatform
+, pkg-config
+, libunwind
+}:
+let
+  cargoToml = builtins.fromTOML (builtins.readFile ../Cargo.toml);
+in
+rustPlatform.buildRustPackage {
+  pname = cargoToml.package.name;
+  version = cargoToml.package.version;
+
+  src = builtins.path {
+    path = ../.;
+  };
+
+  cargoLock.lockFile = ../Cargo.lock;
+
+  buildInputs = [ libunwind ];
+
+  nativeBuildInputs = [ pkg-config ];
+
+  # See https://github.com/NixOS/nixpkgs/blob/nixos-24.05/pkgs/by-name/bu/bugstalker/package.nix#L25-L26
+  doCheck = false;
+
+  meta = {
+    description = "Rust debugger for Linux x86-64";
+    homepage = "https://github.com/godzie44/BugStalker";
+    license = lib.licenses.mit;
+    mainProgram = "bs";
+    platforms = [ "x86_64-linux" ];
+  };
+}

rust-toolchain.toml

@@ -0,0 +1,3 @@
+[toolchain]
+channel = "stable"
+components = ["rust-src", "rust-analyzer"]

src/ui/tui/config/ser.rs

@@ -152,7 +152,7 @@ impl<'de> Deserialize<'de> for WrappedKeyEvent {
     }
 }
 
-#[derive(Serialize, Deserialize)]
+#[derive(Debug, Serialize, Deserialize)]
 struct Common {
     up: Vec<WrappedKeyEvent>,
     down: Vec<WrappedKeyEvent>,
@@ -168,7 +168,7 @@ struct Common {
     input_backspace: Vec<WrappedKeyEvent>,
 }
 
-#[derive(Serialize, Deserialize)]
+#[derive(Debug, Serialize, Deserialize)]
 struct Special {
     switch_window_tab: Vec<WrappedKeyEvent>,
     expand_left: Vec<WrappedKeyEvent>,
@@ -184,7 +184,7 @@ struct Special {
     step_out: Vec<WrappedKeyEvent>,
 }
 
-#[derive(Serialize, Deserialize)]
+#[derive(Debug, Serialize, Deserialize)]
 pub(super) struct KeyMapConfig {
     special: Special,
     common: Common,