nix: flake & non-flake dev shells

.gitignore

@@ -2,4 +2,8 @@
 #
 # SPDX-License-Identifier: CC0-1.0
 
+# Cargo
 target/
+
+# Nix 
+result/

.reuse/dep5

@@ -3,6 +3,6 @@ Upstream-Name: ReGreet
 Upstream-Contact: Harish Rajagopal <[email protected]>
 Source: https://github.com/rharish101/ReGreet
 
-Files: Cargo.lock
+Files: Cargo.lock flake.lock
 Copyright: 2022 Harish Rajagopal <[email protected]>
 License: CC0-1.0

README.md

@@ -243,6 +243,12 @@ pre-commit install
 Now, pre-commit should ensure that the code passes all linters locally before committing.
 This will save time when creating PRs, since these linters also run in CI, and thus fail code that hasn't been linted well.
 
+### Nix/NixOS
+
+Simply run `nix develop .#vscode --command code .` to get VS Code set up with all the extensions you need. The default shell doesnt have any text editors configred.
+
+You can also use nix without flakes if you choose to.
+
 ### Demo mode
 To aid development, a "demo" mode is included within ReGreet that runs ReGreet independent of greetd.
 Simply run ReGreet as follows:

default.nix

@@ -0,0 +1,17 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{pkgs ? import <nixpkgs> {}}: let
+  manifest = (pkgs.lib.importTOML ./Cargo.toml).package;
+in
+  pkgs.rustPlatform.buildRustPackage rec {
+    pname = manifest.name;
+    inherit (manifest) version;
+    cargoLock.lockFile = ./Cargo.lock;
+    src = pkgs.lib.cleanSource ./.;
+
+    buildFeatures = ["gtk4_8"];
+
+    nativeBuildInputs = with pkgs; [pkg-config wrapGAppsHook4];
+    buildInputs = with pkgs; [glib gtk4 pango librsvg];
+  }

flake.nix

@@ -0,0 +1,41 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{
+  description = "Dev tooling for ReGreet";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    supportedSystems = ["x86_64-linux"];
+    forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
+    pkgsFor = nixpkgs.legacyPackages;
+  in {
+    formatter = forAllSystems (system: pkgsFor.${system}.alejandra);
+
+    packages = forAllSystems (system: let
+      pkgs = pkgsFor.${system};
+    in rec {
+      default = regreet;
+      regreet = pkgs.callPackage ./default.nix {inherit pkgs;};
+    });
+
+    devShells = forAllSystems (system: let
+      pkgs = pkgsFor.${system};
+    in {
+      default = pkgs.callPackage ./shell.nix {inherit pkgs;};
+
+      vscode = pkgs.callPackage ./nix/vscode-shell.nix {
+        pkgs = import nixpkgs {
+          inherit system;
+          config.allowUnfree = true;
+        };
+      };
+    });
+  };
+}

nix/vscode-shell.nix

@@ -0,0 +1,20 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{pkgs ? import <nixpkgs> {}}:
+pkgs.mkShell {
+  inputsFrom = [(pkgs.callPackage ../shell.nix {})];
+  buildInputs = with pkgs; [
+    (
+      vscode-with-extensions.override {
+        vscodeExtensions = with vscode-extensions; [
+          rust-lang.rust-analyzer
+          tamasfe.even-better-toml
+          bbenoist.nix
+
+          vscodevim.vim # you can disable this in extension settings if you want
+        ];
+      }
+    )
+  ];
+}

shell.nix

@@ -0,0 +1,19 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{pkgs ? import <nixpkgs> {}}:
+pkgs.mkShell {
+  inputsFrom = [(pkgs.callPackage ./default.nix {})];
+  buildInputs = with pkgs; [
+    rust-analyzer
+    rustfmt
+    clippy
+
+    pre-commit
+  ];
+
+  shellHook = ''
+    echo "Installing pre commit hooks";
+    pre-commit install;
+  '';
+}