GH-29 Change Gradle dsl to Kotlin (#37)

build.gradle.kts

@@ -0,0 +1,37 @@
+plugins {
+    id("java")
+    id("com.github.johnrengelman.shadow") version "7.1.2"
+}
+
+allprojects {
+    group = "io.github.zrdzn.minecraft"
+    version = "1.4.2-SNAPSHOT"
+}
+
+subprojects {
+    apply(plugin = "java")
+    apply(plugin = "com.github.johnrengelman.shadow")
+
+    java {
+        sourceCompatibility = JavaVersion.VERSION_1_8
+        targetCompatibility = JavaVersion.VERSION_1_8
+    }
+
+    tasks.withType<JavaCompile> {
+        options.encoding = "UTF-8"
+    }
+
+    repositories {
+        mavenCentral()
+
+        maven {
+            name = "spigot-repository"
+            url = uri("https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
+        }
+
+        maven {
+            name = "sonatype-repository"
+            url = uri("https://oss.sonatype.org/content/repositories/snapshots")
+        }
+    }
+}

plugin/build.gradle.kts

@@ -0,0 +1,26 @@
+import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
+
+repositories {
+    mavenCentral()
+}
+
+dependencies {
+    implementation(project(":spigot"))
+    implementation(project(":v1_8"))
+    implementation(project(":v1_12"))
+    implementation(project(":v1_13"))
+
+    compileOnly("org.spigotmc:spigot-api:1.8-R0.1-SNAPSHOT")
+
+    implementation("dev.triumphteam:triumph-gui:3.1.4")
+}
+
+java {
+    withSourcesJar()
+}
+
+tasks.withType<ShadowJar> {
+    archiveFileName.set("LovelyDrop v${project.version}.jar")
+
+    relocate("dev.triumphteam.gui", "io.github.zrdzn.minecraft.lovelydrop.gui")
+}

spigot/build.gradle.kts

@@ -0,0 +1,3 @@
+dependencies {
+    compileOnly("org.spigotmc:spigot-api:1.8-R0.1-SNAPSHOT")
+}

v1_12/build.gradle → v1_12/build.gradle.kts

@@ -1,5 +1,5 @@
 dependencies {
     compileOnly(project(":spigot"))
     compileOnly(project(":v1_8"))
-    compileOnly "org.spigotmc:spigot-api:1.12.2-R0.1-SNAPSHOT"
+    compileOnly("org.spigotmc:spigot-api:1.12.2-R0.1-SNAPSHOT")
 }

v1_13/build.gradle → v1_13/build.gradle.kts

@@ -1,5 +1,5 @@
 dependencies {
     compileOnly(project(":spigot"))
     compileOnly(project(":v1_12"))
-    compileOnly "org.spigotmc:spigot-api:1.13-R0.1-SNAPSHOT"
+    compileOnly("org.spigotmc:spigot-api:1.13-R0.1-SNAPSHOT")
 }

v1_8/build.gradle.kts

@@ -0,0 +1,4 @@
+dependencies {
+    compileOnly(project(":spigot"))
+    compileOnly("org.spigotmc:spigot-api:1.8-R0.1-SNAPSHOT")
+}