feat: add SemVerMixin

src/contracts/interfaces/ISemVerMixin.sol

@@ -0,0 +1,11 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity ^0.8.0;
+
+/// @title ISemVerMixin
+/// @notice A mixin interface that provides semantic versioning functionality.
+/// @dev Follows SemVer 2.0.0 specification (https://semver.org/)
+interface ISemVerMixin {
+    /// @notice Returns the semantic version string of the contract.
+    /// @return The version string in SemVer format (e.g., "v1.1.1")
+    function version() external view returns (string memory);
+}

src/contracts/interfaces/ISignatureUtilsMixin.sol

@@ -36,11 +36,6 @@ interface ISignatureUtilsMixinTypes {
  * @notice Terms of Service: https://docs.eigenlayer.xyz/overview/terms-of-service
  */
 interface ISignatureUtilsMixin is ISignatureUtilsMixinErrors, ISignatureUtilsMixinTypes {
-    /// @notice Returns the semantic version string used in the domain separator.
-    /// @return The version string as a regular string (converted from ShortString).
-    /// @dev Returns a SemVer-formatted string with 'v' prefix (e.g., "v1.1.1").
-    function version() external view returns (string memory);
-
     /// @notice Computes the EIP-712 domain separator used for signature validation.
     /// @dev The domain separator is computed according to EIP-712 specification, using:
     ///      - The hardcoded name "EigenLayer"

src/contracts/mixins/SemVerMixin.sol

@@ -0,0 +1,38 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity ^0.8.0;
+
+import "@openzeppelin-upgrades/contracts/utils/ShortStringsUpgradeable.sol";
+import "../interfaces/ISemVerMixin.sol";
+
+/// @title SemVerMixin
+/// @notice A mixin contract that provides semantic versioning functionality.
+/// @dev Follows SemVer 2.0.0 specification (https://semver.org/).
+abstract contract SemVerMixin is ISemVerMixin {
+    using ShortStringsUpgradeable for *;
+
+    /// @notice The semantic version string for this contract, stored as a ShortString for gas efficiency.
+    /// @dev Follows SemVer 2.0.0 specification (https://semver.org/). Prefixed with 'v' (e.g., "v1.2.3").
+    ShortString internal immutable _VERSION;
+
+    /// @notice Initializes the contract with a semantic version string.
+    /// @param _version The SemVer-formatted version string (e.g., "v1.2.3")
+    /// @dev Version should follow SemVer 2.0.0 format with 'v' prefix: vMAJOR.MINOR.PATCH
+    constructor(
+        string memory _version
+    ) {
+        _VERSION = _version.toShortString();
+    }
+
+    /// @notice Returns the semantic version string of the contract
+    /// @return The version string in SemVer format (e.g., "v1.2.3")
+    function version() public view virtual returns (string memory) {
+        return _VERSION.toString();
+    }
+
+    /// @notice Returns the major version of the contract.
+    /// @return The major version string (e.g., "v1" for version "v1.2.3")
+    function _majorVersion() internal view returns (string memory) {
+        bytes memory v = bytes(_VERSION.toString());
+        return string(bytes.concat(v[0], v[1]));
+    }
+}

src/contracts/mixins/SignatureUtilsMixin.sol

@@ -5,6 +5,7 @@ import "@openzeppelin-upgrades/contracts/utils/ShortStringsUpgradeable.sol";
 import "@openzeppelin-upgrades/contracts/utils/cryptography/SignatureCheckerUpgradeable.sol";
 
 import "../interfaces/ISignatureUtilsMixin.sol";
+import "./SemVerMixin.sol";
 
 /// @dev The EIP-712 domain type hash used for computing the domain separator
 ///      See https://eips.ethereum.org/EIPS/eip-712#definition-of-domainseparator
@@ -14,37 +15,22 @@ bytes32 constant EIP712_DOMAIN_TYPEHASH =
 /// @title SignatureUtilsMixin
 /// @notice A mixin contract that provides utilities for validating signatures according to EIP-712 and EIP-1271 standards.
 /// @dev The domain name is hardcoded to "EigenLayer". This contract implements signature validation functionality that can be
-///      inherited by other contracts.
-abstract contract SignatureUtilsMixin is ISignatureUtilsMixin {
-    using ShortStringsUpgradeable for *;
+///      inherited by other contracts. The domain separator uses the major version (e.g., "v1") to maintain EIP-712
+///      signature compatibility across minor and patch version updates.
+abstract contract SignatureUtilsMixin is ISignatureUtilsMixin, SemVerMixin {
     using SignatureCheckerUpgradeable for address;
 
-    /// IMMUTABLES ///
-
-    /// @notice The semantic version string for this contract, stored as a ShortString for gas efficiency.
-    /// @dev Follows SemVer 2.0.0 specification (https://semver.org/). Prefixed with 'v' (e.g., "v1.1.1").
-    ///      WARNING: Modifying this version will invalidate all existing EIP-712 signatures since it changes the domain separator.
-    ShortString private immutable _VERSION;
-
-    /// CONSTRUCTION ///
-
     /// @notice Initializes the contract with a semantic version string.
     /// @param _version The SemVer-formatted version string (e.g., "v1.1.1") to use for this contract's domain separator.
     /// @dev Version should follow SemVer 2.0.0 format with 'v' prefix: vMAJOR.MINOR.PATCH.
-    ///      WARNING: Modifying this version will invalidate all existing EIP-712 signatures since it changes the domain separator.
+    ///      Only the major version component is used in the domain separator to maintain signature compatibility
+    ///      across minor and patch version updates.
     constructor(
         string memory _version
-    ) {
-        _VERSION = _version.toShortString();
-    }
+    ) SemVerMixin(_version) {}
 
     /// EXTERNAL FUNCTIONS ///
 
-    /// @inheritdoc ISignatureUtilsMixin
-    function version() public view virtual returns (string memory) {
-        return _VERSION.toString();
-    }
-
     /// @inheritdoc ISignatureUtilsMixin
     function domainSeparator() public view virtual returns (bytes32) {
         // forgefmt: disable-next-item
@@ -53,7 +39,7 @@ abstract contract SignatureUtilsMixin is ISignatureUtilsMixin {
                 abi.encode(
                     EIP712_DOMAIN_TYPEHASH, 
                     keccak256(bytes("EigenLayer")),
-                    keccak256(bytes(version())),
+                    keccak256(bytes(_majorVersion())),
                     block.chainid, 
                     address(this)
                 )

src/test/unit/mixins/SemVerMixin.t.sol

@@ -0,0 +1,29 @@
+// SPDX-License-Identifier: BUSL-1.1
+pragma solidity ^0.8.0;
+
+import {Test} from "forge-std/Test.sol";
+import {SemVerMixin} from "src/contracts/mixins/SemVerMixin.sol";
+
+// Helper contract to test the abstract SemVerMixin
+contract SemVerMixinMock is SemVerMixin {
+    constructor(string memory version) SemVerMixin(version) {}
+
+    // Expose internal function for testing
+    function majorVersion() public view returns (string memory) {
+        return _majorVersion();
+    }
+}
+
+contract SemVerMixinTest is Test {
+    SemVerMixinMock public semVer;
+
+    function test_version_returnsCorrectVersion() public {
+        semVer = new SemVerMixinMock("v1.2.3");
+        assertEq(semVer.version(), "v1.2.3");
+    }
+
+    function test_majorVersion_returnsCorrectMajorVersion() public {
+        semVer = new SemVerMixinMock("v1.2.3");
+        assertEq(semVer.majorVersion(), "v1");
+    }
+}