Improved IsIsomorphicSemigroup Method

gap/attributes/isomorph.gi

@@ -107,6 +107,69 @@ InstallMethod(IsIsomorphicSemigroup, "for semigroups",
 [IsSemigroup, IsSemigroup],
 {S, T} -> IsomorphismSemigroups(S, T) <> fail);
 
+InstallMethod(IsIsomorphicSemigroup, "for finite simple semigroups",
+[IsSimpleSemigroup and IsFinite, IsSimpleSemigroup and IsFinite],
+function(R, S)
+  local uR, uS, map, mat, next, row, entry, isoR, rmsR, isoS, rmsS;
+
+  # Take an isomorphism of R to an RMS if appropriate
+  if not (IsReesMatrixSemigroup(R) and IsWholeFamily(R)
+      and IsPermGroup(UnderlyingSemigroup(R))) then
+    isoR := IsomorphismReesMatrixSemigroupOverPermGroup(R);
+    rmsR := Range(isoR);
+  else
+    rmsR := R;
+  fi;
+  # Take an isomorphism of S to an RMS if appropriate
+  if not (IsReesMatrixSemigroup(S) and IsWholeFamily(S)
+      and IsPermGroup(UnderlyingSemigroup(S))) then
+    isoS := IsomorphismReesMatrixSemigroupOverPermGroup(S);
+    rmsS := Range(isoS);
+  else
+    rmsS := S;
+  fi;
+
+  uR := UnderlyingSemigroup(rmsR);
+  uS := UnderlyingSemigroup(rmsS);
+
+  if Length(Rows(rmsR)) <> Length(Rows(rmsS)) then
+    return false;
+  fi;
+  if Length(Columns(rmsR)) <> Length(Columns(rmsS)) then
+    return false;
+  fi;
+  if Size(uR) <> Size(uS) then
+    return false;
+  fi;
+  if not IsGroup(uR) then
+    return false;
+  fi;
+  if not IsGroup(uS) then
+    return false;
+  fi;
+
+  map := IsomorphismGroups(uS, uR);
+  if map = fail then
+    return false;
+  fi;
+
+  mat := [];
+  for row in Matrix(rmsS) do
+    next := [];
+    for entry in row do
+      Add(next, entry ^ map);
+    od;
+    Add(mat, next);
+  od;
+
+  # Make sure underlying groups are the same, and then compare
+  # canonical Rees matrix semigroups of both R and S
+  rmsR := CanonicalReesMatrixSemigroup(rmsR);
+  rmsS := ReesMatrixSemigroup(uR, mat);
+  rmsS := CanonicalReesMatrixSemigroup(rmsS);
+  return Matrix(rmsR) = Matrix(rmsS);
+end);
+
 InstallMethod(IsomorphismSemigroups, "for finite simple semigroups",
 [IsSimpleSemigroup and IsFinite, IsSimpleSemigroup and IsFinite],
 function(S, T)
@@ -253,7 +316,7 @@ end;
 InstallMethod(IsomorphismSemigroups, "for semigroups",
 [IsSemigroup, IsSemigroup],
 function(S, T)
-  local invariants, map, DS, DT, p, inv;
+  local invariants, map, p, inv;
 
   # TODO(later) more invariants
   invariants := [IsFinite, IsSimpleSemigroup, IsZeroSimpleSemigroup, Size,
@@ -279,13 +342,12 @@ function(S, T)
     return fail;
   fi;
 
-  DS := SEMIGROUPS.CanonicalDigraph(S);
-  DT := SEMIGROUPS.CanonicalDigraph(T);
-  p := IsomorphismDigraphs(DS[1], DT[1], DS[2], DT[2]);
-  if p = fail then
+  if CanonicalMultiplicationTable(S) <> CanonicalMultiplicationTable(T) then
     return fail;
   fi;
-  p := RestrictedPerm(p, [1 .. Size(S)]);
+  p := CanonicalMultiplicationTablePerm(S)
+       * CanonicalMultiplicationTablePerm(T) ^ -1;
+
   map := x -> AsSSortedList(T)[PositionSorted(S, x) ^ p];
   inv := x -> AsSSortedList(S)[PositionSorted(T, x) ^ (p ^ -1)];
   return SemigroupIsomorphismByFunctionNC(S, T, map, inv);

gap/attributes/isorms.gi

@@ -1368,7 +1368,7 @@ function(S)
 end);
 
 InstallMethod(CanonicalReesMatrixSemigroup,
-"for a Rees 0-matrix semigroup",
+"for a Rees matrix semigroup",
 [IsReesMatrixSemigroup],
 function(S)
   local G, mat;

tst/standard/attributes/isomorph.tst

@@ -9,7 +9,7 @@
 ##
 
 #@local A, BruteForceInverseCheck, BruteForceIsoCheck, F, G, S, T, U, V, inv
-#@local map, x, y
+#@local map, x, y, M, N, R, L
 gap> START_TEST("Semigroups package: standard/attributes/isomorph.tst");
 gap> LoadPackage("semigroups", false);;
 
@@ -118,6 +118,26 @@ gap> T := JonesMonoid(4);
 gap> IsIsomorphicSemigroup(S, T);
 false
 
+# isomorph: IsIsomorphicSemigroup, for finite simple semigroups
+gap> M := [[(1, 2, 3), ()], [(), ()], [(), ()]];
+[ [ (1,2,3), () ], [ (), () ], [ (), () ] ]
+gap> N := [[(1, 3, 2), ()], [(), (1, 2, 3)], [(1, 3, 2), (1, 3, 2)]];
+[ [ (1,3,2), () ], [ (), (1,2,3) ], [ (1,3,2), (1,3,2) ] ]
+gap> R := ReesMatrixSemigroup(AlternatingGroup([1 .. 3]), M);
+<Rees matrix semigroup 2x3 over Alt( [ 1 .. 3 ] )>
+gap> S := ReesMatrixSemigroup(Group([(1, 2, 3)]), N);
+<Rees matrix semigroup 2x3 over Group([ (1,2,3) ])>
+gap> IsIsomorphicSemigroup(R, S);
+true
+gap> L := [[(), ()], [(), ()], [(1, 2, 3), ()]];
+[ [ (), () ], [ (), () ], [ (1,2,3), () ] ]
+gap> T := ReesMatrixSemigroup(SymmetricGroup([1 .. 3]), L);
+<Rees matrix semigroup 2x3 over Sym( [ 1 .. 3 ] )>
+gap> IsIsomorphicSemigroup(S, T);
+false
+gap> IsIsomorphicSemigroup(T, T);
+true
+
 # isomorph: IsomorphismSemigroups, for infinite semigroup(s)
 gap> S := FreeSemigroup(1);;
 gap> T := TrivialSemigroup();;